|
|
看了下上周发布的新版，文件tx_initialize_low_level.s依然接管了xxx.S启动文件已经实现的功能。
从ThreadX的角度来说，他们保证了自己发布新软件包的独立性，直接面向内核出，不需要再面向各个厂家单独出一个系列。
那样工作量就超级大，各大厂家加起来有几千个上万的启动文件。要他们专门去做适配，基本做不到的。
所以他们打算接管xxxx.S启动文件，但接管的文件仅写了几个重要的中断向量表入口。
这就给让移植的人非常不方便。所以我们做的例子不接管XXX.S启动文件了，方便大家移植。
两个都添加进去会提示冲突，必须得二选一：
下面是tx_initialize_low_level.s修改后的，xxx.S启动文件不做任何修改，继续使用。
- ;/**************************************************************************/
- ;/* */
- ;/* Copyright (c) Microsoft Corporation. All rights reserved. */
- ;/* */
- ;/* This software is licensed under the Microsoft Software License */
- ;/* Terms for Microsoft Azure RTOS. Full text of the license can be */
- ;/* found in the LICENSE file at https://aka.ms/AzureRTOS_EULA */
- ;/* and in the root directory of this software. */
- ;/* */
- ;/**************************************************************************/
- ;
- ;
- ;/**************************************************************************/
- ;/**************************************************************************/
- ;/** */
- ;/** ThreadX Component */
- ;/** */
- ;/** Initialize */
- ;/** */
- ;/**************************************************************************/
- ;/**************************************************************************/
- ;
- ;#define TX_SOURCE_CODE
- ;
- ;
- ;/* Include necessary system files. */
- ;
- ;#include "tx_api.h"
- ;#include "tx_initialize.h"
- ;#include "tx_thread.h"
- ;#include "tx_timer.h"
- ;
- ;
- IMPORT _tx_thread_system_stack_ptr
- IMPORT _tx_initialize_unused_memory
- IMPORT _tx_thread_context_save
- IMPORT _tx_thread_context_restore
- IMPORT _tx_timer_interrupt
- IMPORT __main
- IMPORT __Vectors
- IMPORT __initial_sp
- IF :DEF:TX_ENABLE_EXECUTION_CHANGE_NOTIFY
- IMPORT _tx_execution_isr_exit
- IMPORT _tx_execution_isr_enter
- ENDIF
- ;
- ;
- SYSTEM_CLOCK EQU 400000000
- SYSTICK_CYCLES EQU ((SYSTEM_CLOCK / 1000) -1)
- ;
- ;
- ;
- ;
- AREA ||.text||, CODE, READONLY
- PRESERVE8
- ;/**************************************************************************/
- ;/* */
- ;/* FUNCTION RELEASE */
- ;/* */
- ;/* _tx_initialize_low_level Cortex-M7/AC5 */
- ;/* 6.0.1 */
- ;/* AUTHOR */
- ;/* */
- ;/* William E. Lamie, Microsoft Corporation */
- ;/* */
- ;/* DESCRIPTION */
- ;/* */
- ;/* This function is responsible for any low-level processor */
- ;/* initialization, including setting up interrupt vectors, setting */
- ;/* up a periodic timer interrupt source, saving the system stack */
- ;/* pointer for use in ISR processing later, and finding the first */
- ;/* available RAM memory address for tx_application_define. */
- ;/* */
- ;/* INPUT */
- ;/* */
- ;/* None */
- ;/* */
- ;/* OUTPUT */
- ;/* */
- ;/* None */
- ;/* */
- ;/* CALLS */
- ;/* */
- ;/* None */
- ;/* */
- ;/* CALLED BY */
- ;/* */
- ;/* _tx_initialize_kernel_enter ThreadX entry function */
- ;/* */
- ;/* RELEASE HISTORY */
- ;/* */
- ;/* DATE NAME DESCRIPTION */
- ;/* */
- ;/* 06-30-2020 William E. Lamie Initial Version 6.0.1 */
- ;/* */
- ;/**************************************************************************/
- ;VOID _tx_initialize_low_level(VOID)
- ;{
- EXPORT _tx_initialize_low_level
- _tx_initialize_low_level
- ;
- ; /* Disable interrupts during ThreadX initialization. */
- ;
- CPSID i
- ;
- ; /* Set base of available memory to end of non-initialised RAM area. */
- ;
- LDR r0, =_tx_initialize_unused_memory ; Build address of unused memory pointer
- LDR r1, =__initial_sp ; Build first free address
- ADD r1, r1, #4 ;
- STR r1, [r0] ; Setup first unused memory pointer
- ;
- ; /* Setup Vector Table Offset Register. */
- ;
- MOV r0, #0xE000E000 ; Build address of NVIC registers
- LDR r1, =__Vectors ; Pickup address of vector table
- STR r1, [r0, #0xD08] ; Set vector table address
- ;
- ; /* Enable the cycle count register. */
- ;
- ; LDR r0, =0xE0001000 ; Build address of DWT register
- ; LDR r1, [r0] ; Pickup the current value
- ; ORR r1, r1, #1 ; Set the CYCCNTENA bit
- ; STR r1, [r0] ; Enable the cycle count register
- ;
- ; /* Set system stack pointer from vector value. */
- ;
- LDR r0, =_tx_thread_system_stack_ptr ; Build address of system stack pointer
- LDR r1, =__Vectors ; Pickup address of vector table
- LDR r1, [r1] ; Pickup reset stack pointer
- STR r1, [r0] ; Save system stack pointer
- ;
- ; /* Configure SysTick. */
- ;
- MOV r0, #0xE000E000 ; Build address of NVIC registers
- LDR r1, =SYSTICK_CYCLES
- STR r1, [r0, #0x14] ; Setup SysTick Reload Value
- MOV r1, #0x7 ; Build SysTick Control Enable Value
- STR r1, [r0, #0x10] ; Setup SysTick Control
- ;
- ; /* Configure handler priorities. */
- ;
- LDR r1, =0x00000000 ; Rsrv, UsgF, BusF, MemM
- STR r1, [r0, #0xD18] ; Setup System Handlers 4-7 Priority Registers
- LDR r1, =0xFF000000 ; SVCl, Rsrv, Rsrv, Rsrv
- STR r1, [r0, #0xD1C] ; Setup System Handlers 8-11 Priority Registers
- ; Note: SVC must be lowest priority, which is 0xFF
- LDR r1, =0x40FF0000 ; SysT, PnSV, Rsrv, DbgM
- STR r1, [r0, #0xD20] ; Setup System Handlers 12-15 Priority Registers
- ; Note: PnSV must be lowest priority, which is 0xFF
- ;
- ; /* Return to caller. */
- ;
- BX lr
- ;}
- ;
- ;
- ;/* Define shells for each of the unused vectors. */
- ;
- EXPORT __tx_BadHandler
- __tx_BadHandler
- B __tx_BadHandler
- EXPORT __tx_SVCallHandler
- __tx_SVCallHandler
- B __tx_SVCallHandler
- EXPORT __tx_IntHandler
- __tx_IntHandler
- ; VOID InterruptHandler (VOID)
- ; {
- PUSH {r0, lr}
- ; /* Do interrupt handler work here */
- ; /* .... */
- POP {r0, lr}
- BX LR
- ; }
- EXPORT __tx_SysTickHandler
- EXPORT SysTick_Handler
- __tx_SysTickHandler
- SysTick_Handler
- ; VOID TimerInterruptHandler (VOID)
- ; {
- ;
- PUSH {r0, lr}
- IF :DEF:TX_ENABLE_EXECUTION_CHANGE_NOTIFY
- BL _tx_execution_isr_enter
- ENDIF
- BL _tx_timer_interrupt
- IF :DEF:TX_ENABLE_EXECUTION_CHANGE_NOTIFY
- BL _tx_execution_isr_exit
- ENDIF
- POP {r0, lr}
- BX LR
- ; }
- EXPORT __tx_NMIHandler
- __tx_NMIHandler
- B __tx_NMIHandler
- EXPORT __tx_DBGHandler
- __tx_DBGHandler
- B __tx_DBGHandler
- ALIGN
- LTORG
- END
|
|
发表于 2020-8-10 13:01:46
发表于 2020-8-10 13:57:01
楼主
